Oracle Ebs 通过数据库添加请求至请求组

DECLARE
  CURSOR C_PROGRAM IS
    SELECT FCP.CONCURRENT_PROGRAM_ID,
           FCP.CONCURRENT_PROGRAM_NAME,
           FCP.USER_CONCURRENT_PROGRAM_NAME,
           FCP.APPLICATION_ID,
           FA.APPLICATION_SHORT_NAME
      FROM FND_CONCURRENT_PROGRAMS_VL FCP, FND_APPLICATION FA
     WHERE 1 = 1
       AND FCP.APPLICATION_ID = FA.APPLICATION_ID
       AND FCP.USER_CONCURRENT_PROGRAM_NAME = 'CUX_INV_请检入库超出供应需求邮件预警';--请求名称
  CURSOR C_RESP IS
    SELECT FSV.RESPONSIBILITY_NAME,
           FRG.REQUEST_GROUP_NAME,
           FA.APPLICATION_SHORT_NAME,
           FRG.REQUEST_GROUP_ID
      FROM FND_REQUEST_GROUPS    FRG,
           FND_RESPONSIBILITY_VL FSV,
           FND_APPLICATION       FA
     WHERE 1 = 1
       AND FRG.REQUEST_GROUP_ID = FSV.REQUEST_GROUP_ID
       AND FRG.APPLICATION_ID = FSV.APPLICATION_ID
       AND FRG.APPLICATION_ID = FA.APPLICATION_ID
       AND FSV.RESPONSIBILITY_NAME IN ('KH_000_SYS_计划请求设置');--职责名称
  L_CNT NUMBER;
BEGIN
  FOR I IN C_PROGRAM LOOP
    FOR R IN C_RESP LOOP
      L_CNT := 0;
      SELECT COUNT(1)
        INTO L_CNT
        FROM FND_REQUEST_GROUP_UNITS FRQU
       WHERE 1 = 1
         AND FRQU.REQUEST_GROUP_ID = R.REQUEST_GROUP_ID
         AND FRQU.REQUEST_UNIT_ID = I.CONCURRENT_PROGRAM_ID;
      IF L_CNT = 0 THEN
        FND_PROGRAM.ADD_TO_GROUP(PROGRAM_SHORT_NAME  => I.CONCURRENT_PROGRAM_NAME, --请求简称
                                 PROGRAM_APPLICATION => I.APPLICATION_SHORT_NAME, --请求所属应用简称
                                 REQUEST_GROUP       => R.REQUEST_GROUP_NAME, --请求组
                                 GROUP_APPLICATION   => R.APPLICATION_SHORT_NAME); --请求组所属应用简称
      ELSE
      
        DBMS_OUTPUT.PUT_LINE('职责：' || R.RESPONSIBILITY_NAME || ' 已存在请求：' ||
                             I.USER_CONCURRENT_PROGRAM_NAME);
      
      END IF;
    END LOOP;
  END LOOP;

END;